subroutine initu(kappa,l,jdim,jmax,ndim,n,x,t,io,task,u)

c General information:

c     Subroutine initu returns the initial temperature distribution for
c     unsteady heat conduction in a bar.

c     Subroutine initu requires a separate exact solution;
c           function uexa(x,t,kappa,l,io,task).
c     The initial conditions are simply set equal to this exact solution.

c     Copyright 1996 Leon van Dommelen
c     Version 1.0 Leon van Dommelen 12/16/96

c Usage information:

c     Subroutine initu can be called in two different ways depending on
c     the chosen value of parameter task:

c     1. task = 0:
c        This is the standard call. In this case, initu sets u(j,n)
c     equal to uexa(x(j),t(n),...) for all j = 0, 1, ..., jmax for
c     which 0 <= x(j) <= l.

c     2. Any other value:
c        If task is positive, subroutine initu merely initializes itself
c     and exits, otherwise it does nothing at all.

c Arguments:

c     Avoid typos:
      implicit none

c     Input: conduction constant (any restrictions are those of uexa):
      double precision kappa

c     Input: length of the bar (any restrictions are those of uexa):
      double precision l

c     Input: declared maximum mesh point index in arrays x and u:
      integer jdim

c     Input: actual maximum mesh point index:
      integer jmax

c     Input: declared maximum time level index in arrays t and u:
      integer ndim

c     Input: time level to set in array u:
      integer n

c     Input: array of the x-positions of the mesh points:
      double precision x(0:jdim)

c     Input: array of the mesh times t:
      double precision t(0:ndim)

c     Input: I/O unit of an already open output file or zero:
      integer io
c        Subroutine initu will only write to this unit if io is positive.

c     Input: task to perform:
      integer task
c        See the usage information above for more information on task.

c     Output: temperature values:
      double precision u(0:jdim,0:ndim)
c        Provided task equals zero, initu will set the values of u(j,n)
c     to function uexa(x(j),t(n),...) for all j = 0, 1, ..., jmax for
c     which 0 <= x(j) <= l.
c        If task is nonzero, u is ignored.

c External variables and info for compiling or changing subroutine initu:

c     Subroutine initu requires a separate exact solution;
c           function uexa(x,t,kappa,l,io,task).
c     to generate the initial temperature values.
c     For an example exact solution see:
c           ../../u_exa/triangle/u_exa.f
c     For a template for writing new exact solutions see:
c           ../../u_exa/template/u_exa.f
      double precision uexa
      external uexa

c     The following utility routines from ../../../lib/util.f were used:

c        cwrite(module,text,io,show) writes line "text" to I/O unit
c     "io" if nonzero, and to the screen if "show" is nonzero.
      external cwrite

c        fatal(module,text1,text2,text3) kills the program after a
c     fatal error, printing the lines "text1", "text2" and "text3".
      external fatal

c Local variables:

c     An integer to keep track of whether initu has been initialized:
      integer init

c     Mesh point index:
      integer j

c     Constants defined to make changing precision easier:
      double precision zero
      parameter (zero=0.d0)

c     Data statements:
      data init/0/

c Executable statements:

c Ignore negative tasks completely:

      if(task.lt.0)return

c Initialization during the first time that init_u is called:

      if(init.eq.0)then

c        Show which subroutine is being initialized:
         call cwrite('initu',
     &   'Initialization of initial data subroutine initu:',io,0)
         call cwrite('initu','- initializes '//
     &   'the temperatures using an exact solution uexa;',io,0)
         call cwrite('initu',
     &   '- exact/init_u.f Copyright 1996 Leon van Dommelen.',io,0)

c        All done with the initialization:
         init=1

      endif

c Further ignore nonzero tasks:

      if(task.ne.0)return

c Check the sanity of some of the arguments:

      if(jdim.le.0 .or. ndim.lt.0 .or.
     & jmax.le.0 .or. n.lt.0 .or.
     & jmax.gt.jdim .or. n.gt.ndim)call fatal('initu',
     & 'Program error: invalid arguments issued to subroutine out.',
     & 'Fix the program code.',' ')

c Set the initial temperatures using uexa:

      do 100 j=0,jmax
         if(x(j).lt.zero .or. x(j).gt.l)goto 100
         u(j,n)=uexa(x(j),t(n),kappa,l,io,task)
 100  continue
      goto 900

c Exit:

c     Jump here when done:
 900  return
      end