subroutine bc2(kappa,l,jdim,jmax,ndim,n,x,t,io,task,u)

c General information:

c     Subroutine bc2 sets a Dirichlet boundary condition at the right
c     end of a bar.

c     Subroutine bc2 requires a separate exact solution;
c           function uexa(x,t,kappa,l,io,task).
c     The Dirichlet boundary condition is simply set equal to this
c     exact solution.

c     Copyright 1996 Leon van Dommelen
c     Version 1.0 Leon van Dommelen 12/16/96

c Usage information:

c     Subroutine bc2 can be called in three different ways depending on
c     the chosen value of parameter task:

c     1. task = 0:
c        This is the standard call. Subroutine bc2 sets the end point
c     value u(jmax,n) equal to uexa(x(jmax),t(n),...).

c     2. task = -1:
c        This is the inquiry call. Subroutine bc2 changes task to 0 to
c     indicate that it has no special properties.

c     3. Any other value:
c        If task is positive, subroutine bc2 merely initializes itself
c     and exits, otherwise it does nothing at all.

c Arguments:

c     Avoid typos
      implicit none

c     Input: conduction constant (for any restrictions see uexa):
      double precision kappa

c     Input: length of the bar (for any restrictions see uexa):
      double precision l

c     Input: declared maximum mesh point index in arrays x and u:
      integer jdim

c     Input: actual maximum mesh point index:
      integer jmax

c     Input: declared maximum time level index in arrays t and u:
      integer ndim

c     Input: time level to set in array u:
      integer n

c     Input: array of the x-positions of the mesh points:
      double precision x(0:jdim)

c     Input: array of the mesh times t:
      double precision t(0:ndim)

c     Input: I/O unit of an already open output file or zero:
      integer io
c        Subroutine bc2 only writes to this unit if io is positive.

c     Input/Output: task to perform:
      integer task
c        See the usage information above for more information on task.

c     Output: temperature values:
      double precision u(0:jdim,0:ndim)
c        Provided task equals zero, bc2 will set the value of u(jmax,n)
c     to uexa(x(jmax),t(n),...).
c        If task is nonzero, u is untouched.

c External variables and info for compiling or changing subroutine bc2:

c     Subroutine bc2 requires a separate exact solution;
c           function uexa(x,t,kappa,l,io,task).
c     to generate the boundary value.
c     For an example exact solution see:
c           ../../u_exa/triangle/u_exa.f
c     For a template for writing new exact solutions see:
c           ../../u_exa/template/u_exa.f
      double precision uexa
      external uexa

c     The following utility routines from ../../../lib/util.f were used:

c        cwrite(module,text,io,show) writes line "text" to I/O unit
c     "io" if nonzero, and to the screen if "show" is nonzero.
      external cwrite

c        fatal(module,text1,text2,text3) kills the program after a
c     fatal error, printing the lines "text1", "text2" and "text3".
      external fatal

c Local variables:

c     An integer to keep track of whether bc2 has been initialized:
      integer init

c     Data statements:
      data init/0/

c Executable statements:

c For task = -1, change task to zero since bc2 has standard properties:

      if(task.lt.0)then
         task=0
         return
      endif

c Ignore other negative tasks:

      if(task.lt.0)return

c Initialization during the first time that bc2 is called:

      if(init.eq.0)then

c        Show which subroutine is being initialized:
         call cwrite('bc2',
     &   'Initialization of right boundary condition bc2:',io,0)
         call cwrite('bc2','- sets the right '//
     &   'boundary condition using an exact solution uexa;',io,0)
         call cwrite('bc2',
     &   '- diri_exa/bc_2.f Copyright 1996 Leon van Dommelen.',io,0)

c        All done with the initialization:
         init=1

      endif

c Further ignore nonzero tasks:

      if(task.ne.0)return

c Check the sanity of some of the arguments:

      if(jdim.le.0 .or. ndim.lt.0 .or.
     & jmax.le.0 .or. n.lt.0 .or.
     & jmax.gt.jdim .or. n.gt.ndim)call fatal('bc2',
     & 'Program error: invalid arguments issued to subroutine bc2.',
     & 'Fix the program code.',' ')

c Set the boundary point:

      u(jmax,n)=uexa(x(jmax),t(n),kappa,l,io,task)
      goto 900

c Exit:

c     Jump here when done:
 900  return
      end